// Frag Armor

ACTOR FragArmor : CustomInventory 10063
{
  Radius 20
  Height 16
  Inventory.PickupMessage "Frag Armor!"
  Inventory.PickupSound ""
  Inventory.RespawnTics 1050
  Tag "Frag Armor"
  //$Category Health and Armor
  +BASEARMOR
  States
  {
  Spawn:
    ARMA A -1 Bright
    Stop
  Pickup:
    TNT1 A 0 A_JumpIfArmorType("FragArmorProtection","Ammo",300)
    TNT1 A 0 A_JumpIfArmorType("FragArmorProtection","ArmorUpgrade",200)
    TNT1 A 0 A_JumpIfArmorType("BulletArmorProtection","Ammo",200)
    TNT1 A 0 A_JumpIfArmorType("TechArmorProtection","Ammo",200)
    TNT1 A 0 A_JumpIfArmorType("IDMYellowArmor","Ammo",200)
    TNT1 A 0 A_JumpIfArmorType("IDMBlueArmor","Ammo",200)
    TNT1 A 0 A_JumpIfArmorType("IDMRedArmor","Ammo",200)
    TNT1 A 0 A_JumpIfArmorType("PurpleArmor","Ammo",200)
    TNT1 A 0 A_JumpIfArmorType("SuperArmor","Ammo",200)
	TNT1 A 0 A_PlaySound("misc/ammarmor",CHAN_ITEM)
    TNT1 A 0 A_GiveInventory("FragArmorProtection")
    TNT1 A 0 A_GiveInventory("IDMRocketAmmo",15)
	Stop
  ArmorUpgrade:
	TNT1 A 0 A_PlaySound("misc/ammarmor",CHAN_ITEM)
    TNT1 A 0 A_GiveInventory("FragArmorBonus")
    TNT1 A 0 A_GiveInventory("IDMRocketAmmo",15)
	Stop
  Ammo:
	TNT1 A 0 A_PlaySound("misc/ammpkup",CHAN_ITEM)
    TNT1 A 0 A_GiveInventory("IDMRocketAmmo",15)
    Stop
  }
}

ACTOR FragArmorProtection : BasicArmorPickup
{ 
  Radius 20
  Height 16
  Inventory.PickupMessage ""
  Inventory.PickupSound "misc/armpkup"
  Inventory.Icon "ARMAA0"
  Armor.SavePercent 75
  Armor.SaveAmount 200
  DamageFactor "Rocket", 0.125
  DamageFactor "Grenade", 0.125
  DamageFactor "Hellstorm", 0.125
  States
  {
  Spawn:
    TNT1 A 0
    Stop
  }
}

ACTOR FragArmorBonus : BasicArmorBonus
{
	Armor.SavePercent 75
	Armor.SaveAmount 100
	Armor.MaxSaveAmount 200
	Armor.MaxBonus 100
	Armor.MaxBonusMax 100
}